** Chapter 12.4 ** for W.H. Greene, Econometric Analysis6th ed. *****************
* (c) Noel Roy 2003,2008
*
*                 THE HAUSMAN AND WU SPECIFICATION TESTS
*             AND AN APPLICATION TO INTRUMENTAL VARIABLE ESTIMATION
*
* This tutorial will review the following tasks in SHAZAM:
* •	Instrumental Variables estimation (INST command)
* •	Storing covariance matrix of estimates (/COV= option)
* •	Manipulating matrices (MATRIX command)
*
*============================================================================== 
*
* Example 12.4 (p. 324). Hausman Test for a Consumption Function
*
* Often the assumption in the Classical Linear Regesssion Model that
* the independent variables are uncorrelated with the equation error,
* is not true. See the cases in Example 5.2. In these cases, the
* assumption is a misscpecification of the model. 
* Under the null hypothesis of
* no misspecification, OLS will be a consistent and efficient estimator.
* But under the alternative of misspecification OLS will be biased and
* inconsistent.
* The instrumental variables (IV) estimator will not be asymptotically 
* efficient under the null hypothesis but will be appropriate in the 
* presence of misspecification. 
* The Hausman specification error test compares the difference 
* between the two estimators. Under the null hypotheses, IV and OLS
* converge to the same value, but OLS will be more efficient. Under
* the alternate hypothesis, they will converge to different values.
*
* Take as an example the estimation of a consumption function
* C = a + bY + e. Since C enters into the determination of Y,
* then e (which enters into C) and Y will generally be correlated.
* Let us test this hypothesis using quarterly data from Table F5.1.
*
READ (TableF5-1.prn) Year qtr GDP C I G Y/ SKIPLINES=1
*
* Use lagged values of consumption and DPI as instumental variables.
*
GENR LAGC=LAG(C)
GENR LAGY=LAG(Y)
TIME 1950.1 4
*
* Because we have no data for the lagged insrumental variables
* for 1950.1, we must discard this observation.
*
SAMPLE 1950.2 2000.4 
*
* Method 1:
* This procedure is presented in the SHAZAM manual (pp. 432-33
* in the version p manual) which we use as a template.
*
* Estimation using the consistent estimator (IV) under both
* the null and the alternative hypotheses is performed using the
* INST command. Instrumental variables are named in parentheses.
* 
INST C Y (LAGC LAGY) /  COEF=B1 PCOV COV=V1
GEN1 SIGIV=$SIG2
*
* We have saved the vector of IV estimates in B1, the covariance 
* matrix of the estimates in V1, and a consistent estimator of the 
* variance of the equation error in SIGIV.
*
* Estimation using the efficient estimator (OLS) under the null is
*
OLS C Y /  COEF=B0 COV=V0 
GEN1 SIGOLS=$SIG2
*
* We have saved the vector of OLS estimates in B0, the covariance 
* matrix of the estimates in V0, and a consistent estimator of the 
* variance of the equation error in SIGOLS.
*
* The Hausmann statistic uses the same estimate s2 for the variance of the 
* disturbances (bottom of Greene p. 322). The saved covariance matrices
* V0 and V1, however, uses their respective extimates SIGOLS and SIGIV,
* so we must correct one of these estimates. We follow Example 12.4
* in using SIGOLS for both covariance matrices. Correcting V1, 
MATRIX V1=SIGOLS/SIGIV*V1
*
* Compute the Hausman specification test statistic as in p. 322.
*
SAMPLE 1 2
GENR d=B1-B0
MATRIX Vd=V1-V0
MATRIX H=(d(1)**2) / Vd(1,1)
*
* The statistic H is distributed chi-square with 1 degree of freedom
* under the null hypothesis. The 5% critical value is 3.84.
PRINT H
DISTRIB H /TYPE=CHI DF=1

*
* Method 2 (Wu statistic):
*
SAMPLE 1950.2 2000.4 
*
* Get the predicted values in a regression of Y on LAGY and 
* LAGC.
*
?OLS Y LAGY LAGC / PREDICT=YHAT
*
* Regress CONS on GDP and YHAT (equation 5-24).
*
?OLS C Y YHAT
*
* Test the null hypothesis that the coefficient of YHAT is zero.
*
TEST YHAT
STOP
*
*===============================================================================
*
* Updated October 20, 2008