** Chapter 15.8 ** for W.H. Greene, Econometric Analysis 6th ed. *****************
* (c) Noel Roy 2003, 2008
*
*				               SIMULTANEOUS-EQUATIONS MODELS
*                           SPECIFICATION TESTS
*
* This tutorial reviews the following tasks in SHAZAM:
* • Testing overidentifying restrictions (OVERID procedure)
* • Testing variable exogeneity
* • Running SHAZAM Procedures
*
*===============================================================================
*
* Example 13.7 (p. 388) Testing Overidentifying Restrictions 
*
* The overidentification tests in Table 13.4 can be run using the OVERID
* procedure. (see Chapter 41 of the 
* SHAZAM Manual for more information on running SHAZAM procedures).
*
* This procedure requires the same inputs as does the LIML procedure:
* • EXOG: all the exogenous variables in the system.
* • ENDOG: all the endogenous variables in the system.
* • RHSEXOG: the right-hand side exogenous variables in the equation.
* • RHSENDOG: the right-hand side endogenous variables in the equation.
* • LHS: the left-hand side endogenous variable. 
*
* Read Klein's data.
*
TIME 1920 1
SAMPLE 1920.0 1941.0
READ (TableF13-1.prn) / NAMES

* First generate the necessary variables for the model.
*
GENR PLAG=LAG(P)
GENR XLAG=LAG(X)
GENR W=WP+WG
GENR A=YEAR-1931
SAMPLE 1921.0 1941.0
*
* A vector with the value of one will be defined to represent the constant 
* term for use in the necessary matrix computations.
*
GENR ONE=1
*
* Consumption function
EXOG:G T A WG PLAG K1 XLAG
ENDOG:C P W
RHSEXOG:PLAG
RHSENDOG:P W
LHS:C
*
* Now run the PROC (procedure) using the EXEC command.  
*
EXEC OVERID
*
* The procedure reports:
*    - the minimum characteristic root LAMBDA_
*    - Bassman's Lambda prime LAMBDAP_ (based on the 2SLS estimator)
*    - the Likelihood Ratio test statistic LR, along with its degrees of
*      freedom DF and the value of the Cumulative Density Function under 
*      the null hypothesis $CDF
*    - Hausman's T R-squared statistic TRSQ_ (along with its CDF value)
*    - Baseman's F statistic (Lambda-1)*(T-K)/(Kj*-Mj) ~ F(Kj*-Mj,T-K)
*      (along with CDF value)
*    - Baseman's F statistic for Lambda prime FPR_ (with CDF value)
*
* Investment Function
*
EXOG:G T A WG PLAG K1 XLAG
ENDOG:I P
RHSEXOG:PLAG K1
RHSENDOG:P 
LHS:I
EXEC OVERID
*
* Wages equation
*
EXOG:G T A WG PLAG K1 XLAG
ENDOG:WP X 
RHSEXOG:XLAG A
RHSENDOG:X
LHS:WP
EXEC OVERID
*
* Most of the tests are as reported in Tqble 13.4. However, the TR2 test
* results are a little different. This test can be applied using
* the residuals from any efficient limited information estimator, and
* the OVERID procedure uses 2SLS. It is not clear which estimator is
* used in the results reported in Table 13.4, and this could account
* for the discrepancy.
*
* Now test the hypothesis that XLAG is exogenous in the Wages equation of
* Klein's model I.
*
* Estimation using the efficient estimator under the null
* (XLAG is specified as exogenous):
2SLS WP X XLAG A (WG G T PLAG K1 XLAG A) / DN COEF=B0 COV=V0 PCOV
* Estimation using the consistent estimator (IV) under both
* the null and the alternative hypotheses (XLAG not specified
* as exogenous):
2SLS WP X XLAG A (WG G T PLAG K1 A) / DN COEF=B1 PCOV COV=V1 
* Calculate the Wald statistic (13-35):
MATRIX Q=B1-B0
MATRIX VQ=V1-V0
MATRIX WS=Q'INV(VQ)*Q
PRINT WS
DISTRIB WS /TYPE=CHI DF=1
* 
STOP
*
*===============================================================================
* Updated October 22, 2008