** Chapter 19.13 ** for W.H. Greene, Econometric Analysis 6th ed. ****************
* (c) Noel Roy 2003, 2008
*
*	                       SERIAL CORRELATION    
*
*===============================================================================
*
* 19.13 AUTOREGRESSIVE CONDITIONAL HETEROSKEDASTICITY
*
* Example 19.7 (p. 658) Stochastic volatility
*
READ (TableF19-1.prn) /NAMES
*
* Replicate Figure 19.1. The LINEONLY option suppresses the printing of data
* points.
*
GRAPH Y /LINEONLY NOKEY
*
*===============================================================================
* Example 19.8 (p. 665) GARCH Model for Exchange Rate Volatility
*
* LM test for ARCH effects
?STAT Y /MEAN=YBAR
GENR E2=(Y-YBAR)**2
SET NODOECHO
DO #=1,10
GENR ELAG#=LAG(E2,#)
ENDO
?OLS E2 ELAG1-ELAG10 /BEG=11
GEN1 LM=$N*$R2
DISTRIB LM /TYPE=CHI DF=10
*
* The HET command is used to estimate ARCH and GARCH models
* by maximum likelihood. An ARCH(q) model is estimated by 
* setting the option /ARCH=q, and a GARCH(p,q) model by
* setting /ARCH=q GARCH=p (if ARCH=q is absent q=1 is assumed).
* See Chapter 20 of the SHAZAM Manual for further information.
* Estimate a GARCH(1,1) model using the HET command.
*
HET Y /GARCH=1
*
* Note that the parameter labelled delta in the text is named 
* PHI_ here. DELTA_ in the output is an estimate of the
* standard deviation of the pre-sample innovations.
*
*
STOP
*
*===============================================================================
*
* Updated November 10, 2008