** Chapter 20.4 ** for W.H. Greene, Econometric Analysis 6th ed. *****************
* (c) Noel Roy 2003, 2008
*
*                         MODELS WITH LAGGED VARIABLES
*
*===============================================================================
* 20.5 METHODOLOGICAL ISSUES IN THE ANALYSIS OF DYNAMIC MODELS
*
* 20.5.1 An Error Correction Model
*
* Example 20.5 (p. 691) An Error Correction Model for Consumption.
*
*
* Use the TIME command to read in quarterly data.
*
TIME 1950 4
SAMPLE 1950.1 2000.4 
READ (TableF5-1.prn) Year Qtr Y C / SKIPLINES=1
*
* Transform Data into logarithms.
*
GENR C=LOG(C)
GENR Y=LOG(Y)
*
* Replicate Figure 20.3.
*
SAMPLE 1950.1 2000.4
GENR Quarter=YEAR+Qtr/4
GRAPH C Y Quarter / LINEONLY 
*
* Estimate the error correction model by non-linear least squares.
*
SAMPLE 1950.2 2000.4
GENR LC1=LAG(C)
GENR LY1=LAG(Y)
NL 1 /NCOEF=4 COEF=B
EQ C=LC1+MU+BETA0*(Y-LY1)+(GAMMA1-1)*(LC1-THETA*LY1)
END
*
* These results should be similar to those derived from the OLS estimation of
* the linear model.
*
OLS C LC1 Y LY1
TEST -(Y+LY1)/(LC1-1)
*
* Replicate Figure 20.4.
*
GENR EQERROR=(B(3)-1)*(LC1-B(4)*LY1)
GRAPH EQERROR Quarter  / LINEONLY NOKEY 
*
STOP
*
*===============================================================================
* Updated November 12, 2008