** Chapter 22 ** for W.H. Greene, Econometric Analysis 6th ed. *****************
* (c) Noel Roy 2003, 2008
*
*                        NONSTATIONARY DATA
*
*===============================================================================
* 22.2 NONSTATIONARY PROCESSES AND UNIT ROOTS
*
* 22.2.4 The Dickey-Fuller Tests
*
* Example 22.2 (p. 748) Tests for Unit Roots
*
TIME 1950.1 4
SAMPLE 1950.1 2000.4
READ (TableF5-1.prn)Year qtr realgdp realcons realinvs realgovt realdpi cpi M1 i unemp pop pi realint / SKIPLINES=1
* Replicate Figure 22.5:
GENR y=LOG(realgdp)
GRAPH y /LINEONLY NOKEY
* Replicate Figure 22.4.
SAMPLE 1950.2 2000.4
GRAPH Pi /LINEONLY NOKEY
*
* Create series for change in the log of M1 (delm) and real growth in the
* money stock (realdelm).
GENR delm=LOG(M1)-LOG(LAG(M1))
GENR realdelm=delm-pi
* 
* Replicate Figures 22.6-22.9.
GRAPH i /LINEONLY NOKEY
GRAPH delm /LINEONLY NOKEY
GRAPH realint /LINEONLY NOKEY
GRAPH realdelm /LINEONLY NOKEY
*
* The COINT command implements tests for unit roots and cointegration.
*   In general, the format is:
*    COINT vars / options
*   where vars is a list of variable names.
*
* By default, SHAZAM runs AUGMENTED Dickey-Fuller tests on the named variables.
* The NLAG= option can specify the number of lag terms in the Dickey-Fuller
* regressions. If this is not specified then the order is set as the highest 
* significant lag order from either the ACF or PACF of the first differenced series.
* The simple Dickey-Fuller tests in Table 20.6 are generated with the DLAG=0
* option.
* The SIGLEVEL= option specifies the significance level for the critical values.
* The available choices are 1, 5, and 10 (default).
* The COINT command is described further in Chapter 13 of the SHAZAM Manual.
*
* The COINT command reports results for Dickey-Fuller regressions involving
* a constant term (CONSTANT, NO TREND) as well as one involving a constant
* term and time trend (CONSTANT, TREND). Since only y is trended, the
* former test is the appropriate one for all other variables.
* Several test statistics are reported, including DF_tau (labelled T-TEST)
* and DF_gamma (labelled Z-TEST). As well, the result of joint F-tests 
* involving the contatnt term A(0) and time trend A(2) as well as the lag
* term A(1) are presented.
*
COINT Pi y i delm realint realdelm /NLAG=0 SIGLEVEL=5 
*
*===============================================================================
* Example 22.3 (p. 754) Augmented Dickey-Fuller Test for a Unit Root in GDP
*
* Test for a unit root, using both one lag and the SHAZAM default.
COINT Y /SIGLEVEL=5 NLAG=1
COINT Y /SIGLEVEL=5
*
* The Phillips and Perron test is generated by COINT when the TYPE=PP option 
* is taken. Again, use both L=4 and the SHAZAM default for the truncation
* parameter, which can be set by the NLAG= option.
COINT Y /TYPE=PP NLAG=4
COINT Y /TYPE=PP
*

STOP
*
*===============================================================================
* Updated November 19, 2008