** Chapter 4.7.2 ** for W.H. Greene, Econometric Analysis 6th ed. *****************
* (c) Noel Roy 2003, 2008
*
*             THE NORMALITY ASSUMPTION AND BASIC STATISTICAL INFERENCE
*                   4.7.2 Confidence Intervals for Parameters
*
* The tutorial for this chapter will review the following tasks in SHAZAM:
*   •	Confidence intervals (CONFID command)
*   •	Testing hypotheses (TEST command)
*
*===============================================================================
*
* Example 4.4 (p. 55) Confidence Interval for the Income Elasticity of Demand 
* for Gasoline
*
TIME 1953.0 1
SAMPLE 1953.0 2004.0
READ (TableF2-2.txt) Year,GasExp,Pop,Gasp,Income,PNC,PUC,PPT,PD,PN,PS /SKIPLINES=1 
*
GENR lnGpop = LOG(GasExp/Pop/Gasp)
GENR lnincome = LOG(Income)
GENR lnPg = LOG(Gasp)
GENR lnPnc = LOG(Pnc)
GENR lnPuc = LOG(Puc)
*
* The option LOGLOG in an OLS command is used when the dependent variable
* and all the independent variables are in LOG form, so that the elasticities
* and the values of the log-likelihood function are presented correctly.
*
OLS lnGpop lnPg lnincome lnPnc lnPuc / LOGLOG
*
* The CONFID command will generate a lower and upper bound of confidence
* around a point estimate of a parameter from the preceding regression.
*
CONFID lnincome
*
* The TEST command (which must be immediately preceded by an estimation command)
* can test the null hypothesis that the true value of the coefficient of Ln(Y) is 1.
*
TEST lnincome=1
*
* The TEST command gives the results of t and F tests, which depend on the 
* assumption of normality of the estimates, and the Wald statistic, which 
* does not depend on normality but is only asymptotically 
* valid. See Chapter 5 of the textbook for further information.

* The upper bound on the p-value is based on the Chebychev inequality, 
* which states (equation B-18) that if x is a random variable, xo its mean, 
* and s its standard deviation,  Pr ( | x - xo | =< ks ) >= 1 - 1/k**2,
* where k is any positive constant. This is true irrespective of how x is 
* distributed. 
*
* For the above example, the test statistic has a value 0.37340, which under 
* null hypothesis has mean zero and a standard deviation that is estimated as 
* 0.75628E-01. The condition | x - xo | =< ks can then be true only if 
* k =< 4.947. Values in excess of this can occur only with probability 
* 1/k**2=0.04102. This is the highest probability that the test statistic 
* could exceed the value 0.37340 under the null hypothesis, and so represents 
* an upper limit to the p-value of the test statistic that is independent of 
* distributional assumptions. The implication is that at a 5% level of
* significance, we should not be overly concerned about the possibility
* that our estimates may not be normally distributed.  
* Note, however, that this conclusion is dependent on an estimate 
* of the standard deviation which may be only approximate in small samples.
*
STOP
*
*===============================================================================
*
* Updated August 27, 2008