** Chapter 4.7.4 ** for W.H. Greene, Econometric Analysis 6th ed. *****************
* (c) Noel Roy 2003, 2008
*
*             FINITE-SAMPLE PROPERTIES OF THE LEAST SQUARES ESTIMATOR
*              4.7.4 Testing the Significance of the Regression
*
* The tutorial for this chapter will review the following tasks in SHAZAM:
*   •	Using temporary variables
*
*===============================================================================
*
* Example 4.5 (p.57) F Test for the Earnings Equation
*
* The F test for significance of the regression is not generated by default, but
* will be produced with the output from the ANOVA option.
*
SAMPLE 1 753
READ (TableF4-1.prn) LFP WHRS KL6 K618 Age Educatn WW /SKIPLINES=37
SET NOWARNSKIP
SKIPIF (1-LFP)
GENR LNEARN=LOG(WW*WHRS)
GENR Age2=Age**2
GENR Kids=DUM(KL6+K618)
*
OLS LNEARN Age Age2 Educatn Kids /ANOVA LOGLIN
*
* Alternatively, the formula (4-16) for the F-statistic can be calculated with
* the use of "temporary variables". These are variables that are created 
* internally by SHAZAM for its own purposes, but are also available for use by
* the user. However, temporary variables must be used (or stored in another
* variable) immediately after the procedure that creates them is run, since 
* they are redefined when another procedure is run.

* All temporary variables have a name that begins with the $ symbol. OLS creates
* $N for the sample size, $K for the number of independent variables, and $R2 
* for the R-squared. The value of the F-statistic by (4-15) can be computed 
* with the GEN1 command.
*
GEN1 $R2/($K-1)/((1-$R2)/($N-$K))
STOP
*
*===============================================================================
*
* Updated August 27, 2008