** Chapter 4.9.4 ** for W.H. Greene, Econometric Analysis 6th ed. *****************
* (c) Noel Roy 2008
*
*             Nonlinear functions of Parameters: the Delta Method
*
*===============================================================================
*
* Example 4.7 (p. 69) 
*
* The delta method is implemented in SHAZAM through the TEST command.
*
* From Example 4.4,
TIME 1953.0 1
SAMPLE 1953.0 2004.0
READ (TableF2-2.txt) Year,GasExp,Pop,Gasp,Income,PNC,PUC,PPT,PD,PN,PS /SKIPLINES=1 
*
GENR lnGpop = LOG(GasExp/Pop/Gasp)
GENR lnincome = LOG(Income)
GENR lnPg = LOG(Gasp)
GENR lnPnc = LOG(Pnc)
GENR lnPuc = LOG(Puc)
*
* Creating the lagged dependent variable,
GENR lnGpop1 = LAG(lnGpop)
*
* Because the lagged variable is not defined for 1953, we must reset the
* sample.
SAMPLE 1954.0 2004.0
OLS lnGpop lnPg lnincome lnPnc lnPuc lnGpop1 / LOGLOG PCOV
*
* Estimating the values and standard errors for the long-run elasticities:
*
TEST lnPg/(1-lnGpop1)
TEST lnincome/(1-lnGpop1)
*
STOP
*
*===============================================================================
*
* Updated August 28, 2008