** Chapter 5.3.1 ** for W.H. Greene, Econometric Analysis 6th ed. *****************
* (c) Noel Roy 2003
*
*                        TESTING HYPOTHESES
*
* The tutorial for this section will review the following tasks in SHAZAM:
* •	Joint hypothesis testing (TEST. . .END sequence)
*
*===============================================================================
*
* 5.3 TWO APPROACHES TO TESTING HYPOTHESES
*
* 5.3.1 The F Statistic and the Least Squares Discrepancy
*
* Example 5.1 (p. 86) Restricted Investment Equation
*
* The investment data is obtained from the quarterly data in Table F5.1.
* We lose the first observation through calculation of the rate of inflation.
*
READ (TableF5-1.prn)Year qtr realgdp realcons realinvs realgovt realdpi cpi M1 i unemp pop deltap realint / SKIPLINES=1
*
* Estimate both the restricted model (5-3) and the unrestricted model (5-1).
*
TIME 1950.1 4
SAMPLE 1950.2 2000.4
GENR lnI=LOG(realinvs)
GENR lnY=LOG(realgdp)
GENR t=TIME(-1)
*
* Since realint=i-deltap, the restricted model is
*
OLS lni realint lny t
*
* The unrestricted model has both i and deltap instead of realint.
*
OLS lnI i deltap lny t /PCOV
*
* Test the null hypothesis that b2+b3=0, which is equivalent to the
* restricted model.
*
TEST i+deltap
*
* Test the restricted model directly:
*
OLS lnI realint deltap lny t 
*
* Now test the joint hypothesis that b2+b3=1, b4=1 and b5=0 are 
* true. A joint test of more than one hypothesis is done by
* placing the TEST commands between a TEST statement and an END
* statement, as follows (Note that the TEST command must 
* immediatly follow the the command generating the estimates
* on which the test is based).
*
?OLS lnI i deltap lny t 
TEST
TEST i+deltap
TEST lny=1
TEST t
END
*
* The three restrictions can be tested one at a time with simple
* TEST commands.
*
TEST i+deltap
TEST lny=1
TEST t
STOP
*
* Updated Auguest 28, 2008