** Chapter 5.3.3 ** for W.H. Greene, Econometric Analysis 6th ed. *****************
* (c) Noel Roy 2003, 2008
*
*                        The Restricted Least Squares Estimator
*
* The tutorial for this chapter will review the following tasks in SHAZAM:
* •	Joint hypothesis testing (TEST. . .END sequence)
* •	Restricted estimation (RESTRICT option)
*
*===============================================================================
*
* 5.3.3 The Loss of Fit from Restricted Least Squares
*
* Example 5.2 (p. 90)  Production Function
*
SAMPLE 1 27
READ (TableF5-2.prn)  / NAMES
GENR lnY=LOG(ValueAdd)
GENR lnL=LOG(Labor)
GENR lnK=LOG(CAPITAL)
* 
* Run an OLS regression on the Cobb-Douglas production function.
*
OLS lnY lnL lnK / PCOV 
*
* Test the null hypothesis that the production function exhibits constant 
* returns to scale.
*
TEST lnL+lnK=1
*
* Estimate the "translog" model using OLS.
*
GENR ln2L=lnL**2/2
GENR ln2K=lnK**2/2
GENR lnLlnK=lnL*lnK
OLS lnY lnL lnK ln2L ln2K lnLlnK / PCOV
*
* Test the null hypothesis for the Cobb-Douglas model, which 
* implies that the coefficients on the additional variables
* in the unrestricted model are jointly equal to zero.
*
TEST
TEST ln2L=0
TEST ln2K=0
TEST lnLlnK=0
END
*
* Test the null hypothesis that the translog production function 
* exhibits constant returns to scale.
*
TEST
TEST lnK+lnL=1
TEST ln2L+ln2K+2*lnLlnK=0
END
*
* The Cobb-Douglas production function with the restriction 
* Beta2=1 can be estimated as follows:
*
GENR lnYL = lnY-lnL
OLS lnYL lnK
*
* However SHAZAM directly supports the imposition of linear
* restrictions, and this generally provides more satisfactory
* results. For example, R-squared is calculated properly, and
* the validity of the restricton is tested.
* The format to be used for Restricted Least Squares is:
* 
* OLS depvar indeps / RESTRICT options
* RESTRICT equation1
* RESTRICT equation2
* ...
* END
* 
* where the equations are linear functions of the variables 
* (representing coefficients).
*
* For example, a Cobb-Douglas production function with the
* coefficient for lnL restricted to unity is estimated as
*
OLS lnY lnL lnK / RESTRICT
RESTRICT lnL=1
END
*
* We can calculate the capital elasticity of output, and
* its standard error. First, staTe the mean values for 
* lnL and lnK.
*
?STAT lnL /MEAN=lnLbar
?STAT lnK /MEAN=LnKbar
?OLS lnY lnL lnK ln2L ln2K lnLlnK 
* 
* After estimating the translog, TEST the value of the function
* that defines the capital elasticity.
TEST lnK+ln2K*lnKbar+lnLlnK*lnLbar
*
STOP
STOP
*
*===============================================================================
*
* Updated August 28, 2008